Holt Researcher: American History/Holt Researcher: American History.iso/pc/modules/grph.dxr/00016_print button.ls

Text File | 2000-01-28 | 1.6 KB | 61 lines

property ancestor, pMIAW
global gIsRolloverTextOn

on new me, buttonName, castName, theChannel, theStageLoc, theBalloonChannel, theBalloonLoc, descendant
  if objectp(descendant) then
    ancestor = new(script("button with balloon"), buttonName, castName, theChannel, theStageLoc, theBalloonChannel, theBalloonLoc, descendant)
  else
    ancestor = new(script("button with balloon"), buttonName, castName, theChannel, theStageLoc, theBalloonChannel, theBalloonLoc, me)
  end if
  set the cursor of sprite the pChannel of me to [member("point hand", "graph.cst"), member("point hand mask", "graph.cst")]
  return me
end

on setMIAW me, miaw
  pMIAW = miaw
  return me
end

on performFunction me
  global gEnvironObj, gGraph
  tell the stage
    playSFX(5)
  end tell
  if not isMemoryAvailable("print the document", 1200, 500) then
    exit
  end if
  doc = new(xtra("PrintOMatic"))
  if not objectp(doc) then
    alert("A problem was encountered while initializing the printer.")
    exit
  else
    setLandscapeMode(doc, 1)
    pageW = getPageWidth(doc)
    pageH = getPageHeight(doc)
    setTextJust(doc, "centered")
    append(doc, member("title", "internal"))
    append(doc, RETURN & RETURN & RETURN)
    drawStagePicture(doc, point(0, 36), rect(4, 40, 635, 404), 1)
    setDocumentName(doc, "American History")
    if doJobSetup(doc) then
      print(doc)
    end if
    doc = 0
  end if
  return me
end

on performRolloverFunction me
  if gIsRolloverTextOn then
    performRolloverFunction(ancestor)
  end if
  return me
end

on performRolloffFunction me
  if gIsRolloverTextOn then
    performRolloffFunction(ancestor)
  end if
  return me
end